Login Message

cbk1994 · #1 11-25-2007, 02:48 AM

Here's the login message that is used on Utopia. I'm releasing it to the public, since it's not getting too much use here.

The files are control/serverNews.txt, control/serverHirings.txt, control/serverStaff.txt, and control/serverInfo.txt. Change these files to change what text shows up when you log on.

Script of Weapon/GUI-Script -System/LoginMessage:

PHP Code:


			
function onActionServerSide( cmd )

{

  if ( cmd == "getMessage" )

  {

    temp.n.loadLines( "control/serverNews.txt" );

    temp.h.loadLines( "control/serverHirings.txt" );

    temp.s.loadLines( "control/serverStaff.txt" );

    temp.i.loadLines( "control/serverInfo.txt" );

    triggerclient( "gui", name, "returnMessage", temp.n, temp.h, temp.s, temp.i );

  }

}

//#CLIENTSIDE

function onCreated()

{

  triggerserver( "gui", name, "getMessage" );

}

function onActionClientSide( cmd, n, h, s, i )

{

  if ( cmd == "returnMessage" )

  {

    for ( temp.a : n )

    {

      temp.ne @= temp.a @ "\n";

    }

    

    for ( temp.a : h )

    {

      temp.hi @= temp.a @ "\n";

    }

    

    for ( temp.a : s )

    {

      temp.st @= temp.a @ "\n";

    }

    

    for ( temp.a : i )

    {

      temp.inf @= temp.a @ "\n";

    }

    

    showMessage( temp.ne, temp.hi, temp.st, temp.inf );

  }

}

function showMessage( news, hirings, staff, info )

{

  new GuiWindowCtrl( "LoginMessage_Window" )

  {

    profile = "GuiBlueWindowProfile";

    

    width = 440;

    height = 368;

    

    x = screenwidth / 2 - ( width / 2 );

    y = screenheight / 2 - ( height / 2 );

    

    canMaximize = canResize = false;

    canClose = canMinimize = visible = title = true;

    

    text = "Welcome to" SPC servername @ "!";

    

    new GuiScrollCtrl( "LoginMessage_NewsScroll" )

    {

      profile = "GuiBlueScrollProfile";

      

      x = 15;

      y = 54;

      

      width = 410;

      height = 300;

      

      vScrollBar = "dynamic";

      hScrollBar = "alwaysOff";

      

      visible = false;

      

      new GuiMLTextCtrl( "LoginMessage_NewsText" )

      {

        profile = "GuiBlueTextProfile";

        

        x = 3;

        y = 0;

        

        width = 390;

        height = 300;

        

        text = news;

      }

    }

    

    new GuiScrollCtrl( "LoginMessage_HiringsScroll" )

    {

      profile = "GuiBlueScrollProfile";

      

      x = 15;

      y = 54;

      

      width = 410;

      height = 300;

      

      vScrollBar = "dynamic";

      hScrollBar = "alwaysOff";

      

      visible = false;

      

      new GuiMLTextCtrl( "LoginMessage_HiringsText" )

      {

        profile = "GuiBlueTextProfile";

        

        x = 3;

        y = 0;

        

        width = 390;

        height = 300;

        

        text = hirings;

      }

    }

    

    new GuiScrollCtrl( "LoginMessage_StaffScroll" )

    {

      profile = "GuiBlueScrollProfile";

      

      x = 15;

      y = 54;

      

      width = 410;

      height = 300;

      

      vScrollBar = "dynamic";

      hScrollBar = "alwaysOff";

      

      visible = false;

      

      new GuiMLTextCtrl( "LoginMessage_StaffText" )

      {

        profile = "GuiBlueTextProfile";

        

        x = 3;

        y = 0;

        

        width = 390;

        height = 300;

        

        text = staff;

      }

    }

    

    new GuiScrollCtrl( "LoginMessage_InfoScroll" )

    {

      profile = "GuiBlueScrollProfile";

      

      x = 15;

      y = 54;

      

      width = 410;

      height = 300;

      

      vScrollBar = "dynamic";

      hScrollBar = "alwaysOff";

      

      visible = false;

      

      new GuiMLTextCtrl( "LoginMessage_InfoText" )

      {

        profile = "GuiBlueTextProfile";

        

        x = 3;

        y = 0;

        

        width = 390;

        height = 300;

        

        text = info;

      }

    }

    new GuiTabCtrl( "LoginMessage_Tab" )

    {

      profile = "GuiBlueTabProfile";

      

      x = 35;

      y = 30;

      

      width = 450;

      height = 24;

      

      tabwidth = 90;

      

      clearRows();

      

      temp.r = {

                 { "News", "LoginMessage_NewsScroll" },

                 { "Hirings", "LoginMessage_HiringsScroll" },

                 { "Staff", "LoginMessage_StaffScroll" },

                 { "Info", "LoginMessage_InfoScroll" }

               };

      

      for ( temp.a : temp.r )

      {

        with ( addRow( 0, temp.a[0] ) )

        {

          this.iPane = temp.a[1];

        }

      }

      thiso.catchevent( name, "onSelect", "onTabSelected" );

      setSelectedRow( 0 );

    }

  }

}

function onTabSelected( tabs )

{

  for ( temp.t : tabs.rows )

  {

    if ( temp.t == tabs.selected )

    {

      ( @ temp.t.iPane[0] ).visible = true;

    }

    else

    {

      ( @ temp.t.iPane[0] ).visible = false;

    }

  }

}

Attached are some screenshots. Please give me feedback!

foxboi · #2 11-26-2007, 04:42 AM

how is this GUI activated?

cbk1994 · #3 11-26-2007, 05:18 AM

When you login, it will open.
Otherwise, I suppose you could map it so a key would open it, or a specific chat. Tell me if you need help with that!

EDIT:
Also, I forgot to point out that you'll need to add these rights to (npcserver)

r control/*.txt

so that it can read the files.

foxboi · #4 11-26-2007, 02:51 PM

It would be awesome if you could post a onKeyPressed or onPlayerChat function for it.

Codein · #5 11-26-2007, 03:30 PM

Quote:

Originally Posted by foxboi

It would be awesome if you could post a onKeyPressed or onPlayerChat function for it.

If you look at other scripts and Gscript guides, I suppose you could learn to implement it yourself. It's actually quite logical.

foxboi · #6 11-27-2007, 12:14 AM

Ah.kk

cbk1994 · #7 11-29-2007, 01:56 AM

Add either of these below the //#CLIENTSIDE.

for chat

PHP Code:


			
function onPlayerChats()
{
  if ( player.chat == "/menu" )
  {
    triggerserver( "gui", name, "getMessage" );
  }
}

and for a button

PHP Code:


			
function onKeyPressed( code, key )
{
  if ( key == "w" )
  {
    triggerserver( "gui", name, "getMessage" );
  }
}

Tell me if you need any help with this!

Knightmare1 · #8 12-15-2007, 07:29 PM

its till not working for me

pokeSMOT · #9 02-07-2008, 09:42 PM

For this type of code, do you just create a blank "weapon" npc, give folder rights, and also make these four text docs?

edit: I get the following error, as it refers to this --
"triggerserver( "gui", name, "getMessage" ); "

ERROR: GraalScript: Function triggerserver not found at line 15 in script of -LoginMessage

Any suggestions?

Chompy · #10 02-07-2008, 09:45 PM

Quote:

Originally Posted by pokeSMOT

For this type of code, do you just create a blank "weapon" npc, give folder rights, and also make these four text docs?

Not a blank weapon npc :P You put in the code in the PHP tags into it. The textfiles is for loading news/text to display

zokemon · #11 02-07-2008, 10:17 PM

Quote:

Originally Posted by pokeSMOT

For this type of code, do you just create a blank "weapon" npc, give folder rights, and also make these four text docs?

edit: I get the following error, as it refers to this --
"triggerserver( "gui", name, "getMessage" ); "

ERROR: GraalScript: Function triggerserver not found at line 15 in script of -LoginMessage

Any suggestions?

If that is the case, the //#CLIENTSIDE probably was typed wrong or the trigger was called serverside since triggerserver is clientside only.
Was the error in RC?

cbk1994 · #12 02-07-2008, 11:13 PM

Quote:

Originally Posted by zokemon

If that is the case, the //#CLIENTSIDE probably was typed wrong or the trigger was called serverside since triggerserver is clientside only.
Was the error in RC?

Also it should not be checking the functions clientside, right?

Don't those go into F2 upon execution?

pokeSMOT · #13 02-09-2008, 12:26 AM

Yes, I still get this error in RC
GraalScript: Function triggerserver not found at line 15 in script of -System/LoginMessage

=-=-=-=-=-=-=-=-=-=
//#CLIENTSIDE
function onCreated()
{
triggerserver( "gui", name, "getMessage" );
}
=-=-=-=-=-=-=-=-=-=

That block of code is still getting an error for some reason

cbk1994 · #14 02-09-2008, 01:08 AM

Quote:

Originally Posted by pokeSMOT

Yes, I still get this error in RC
GraalScript: Function triggerserver not found at line 15 in script of -System/LoginMessage

=-=-=-=-=-=-=-=-=-=
//#CLIENTSIDE
function onCreated()
{
triggerserver( "gui", name, "getMessage" );
}
=-=-=-=-=-=-=-=-=-=

That block of code is still getting an error for some reason

If you like, if you are on I can come and help you?

Inverness · #15 02-09-2008, 02:56 AM

Make sure there is not a space at the end of //#CLIENTSIDE, I believe that can mess it up.