GuiScrollCtrl - Getting max y pos

[jamitsu89]

Is there a way to check the maximum Y position of a Gui Scroll Control?

Think Client RC. If chat scroll is at the bottom when more text is added, it scrolls down and shows it, whereas if scroll bar is up a tad, it doesn't scroll down to encompass the new text - it simply stays where it is.

EDIT- Nobody knows how to get a similar effect to the Client RC?

[jamitsu89]

Well, in case anyone else also has this problem, I'll post my solution:

PHP Code:

temp.origposition = GuiScrollCtrl.scrollpos;

GuiScrollCtrl.scrolltobottom();

temp.maxposition = GuiScrollCtrl.scrollpos;



if (temp.origposition[1] < temp.maxposition[1])

  GuiScrollCtrl.scrollTo(temp.origposition[0], temp.origposition[1]); 


An unfortunate work around, and doesn't always work, but seems the only way.

[fowlplay4]

Try this:

PHP Code:

//#CLIENTSIDE
function onRCChat() {
  GuiChatScroll.scrolltobottom();
} 


You'll have to replace the GUI object's name obviously.

[cbk1994]

Originally Posted by fowlplay4

Try this:

PHP Code:

//#CLIENTSIDE
function onRCChat() {
  GuiChatScroll.scrolltobottom();
} 


You'll have to replace the GUI object's name obviously.

I think what he's trying to do instead is make a GuiScrollCtrl scroll to the bottom when the height increases only when it was already scrolled to the bottom.

[fowlplay4]

I feel like that would trigger a GuiScrollControl.onResize() and you can do the same thing there.

PHP Code:

//#CLIENTSIDE
function GuiScrollControl.onResize() { 
  GuiScrollControl.scrolltobottom();
} 


[cbk1994]

Originally Posted by fowlplay4

I feel like that would trigger a GuiScrollControl.onResize() and you can do the same thing there.

PHP Code:

//#CLIENTSIDE
function GuiScrollControl.onResize() { 
  GuiScrollControl.scrolltobottom();
} 


Except the problem is he only wants to scroll down if it's already scrolled to the bottom. If someone chats in RC but you've scrolled up, it doesn't automatically scroll down for you (that would be annoying).

[Tigairius]

This is how I did it in the Client RC (copied/pasted directly out of the script):

PHP Code:

    // Changed this so RC will scroll back to 
    // normal position. -Tig
    
    // Store the old position before adding text
    temp.oldpos = ScriptedRCScroll.scrollpos;
    
    // Need to get the position of scroll when it's
    // at the bottom
    ScriptedRCScroll.scrollToBottom();
    temp.maxscroll = ScriptedRCScroll.scrollpos[1];
    
    ScriptedRCRCchat.text @= "\n" @ temp.data;
        
    // If the scroll wasn't at the bottom, then don't
    // scroll to back to the bottom.
    if (temp.oldpos[1] != temp.maxscroll) {
      ScriptedRCScroll.scrollTo(temp.oldpos[0], temp.oldpos[1]);
    } else {
      ScriptedRCScroll.scrollToBottom();
    }
    
    // Check to see if the text is bigger than the scroll
    // viewing window, if not, scrolltobottom.
    // Makes sure it will move the scroll down to the bottom
    // if there was previously no scroll showing.
    if (ScriptedRCRCchat.clientheight < ScriptedRCScroll.clientheight + ScriptedRCRCchat.profile.getTextHeight()) {
      ScriptedRCScroll.scrollToBottom();
    } 


[jamitsu89]

Ah lovely, thanks a lot Tig.
And cheers for responding, Jer and Chris.