Sword-Specific Level

[godofwarares]

Originally Posted by Twinny

Umm... you can't set a players sword power or hearts clientside. Also, this.firstpower and this.firsthearts are undefined. You also managed to mix up the order (clientr. is set when the player leaves?).

I'll write it in GS2 first and i'll try and work it out in GS1

PHP Code:

function onCreated()
{
  this.sethearts=10;
  this.setsword=2;
}

function onPlayerEnters()
{
  player.clientr.setsword = player.swordpower;
  player.clientr.sethearts = player.fullhearts;
  player.swordpower = this.setsword;
  player.fullhearts = this.sethearts;
  player.chat = "Default stats set!";
}

function onPlayerLeaves()
{
  player.swordpower = player.clientr.setsword;
  player.fullhearts = player.clientr.sethearts;
  player.clientr.setsword = "";
  player.clientr.sethearts = "";
  player.chat = "Original Stats Restored";
} 


In GS1:

PHP Code:

if (created)
{
     this.sethearts = 10;
     this.setsword = 2;
}

if (playerenters)
{
     setstring clientr.setsword, playerswordpower;
     setstring clientr.sethearts, playerfullhearts;
     playerswordpower = this.setsword;
     playerfullhearts = this.sethearts;

     setplayerprop #c,Default stats set!;
}

if (playerleaves)
{
     playerswordpower = clientr.setsword;
     playerfullhearts = clientr.sethearts;
     setstring clientr.setsword,;
     setstring clientr.sethearts,;

     setplayerprop #c,Original Stats Restored;
} 


* I love how when people ask for GS1, everyone gives him GS2 ...

[Twinny]

Originally Posted by godofwarares

* I love how when people ask for GS1, everyone gives him GS2 ...

I skipped GS1 all together so I don't know it all. I post a solution in GS2 in case the original poster / someone else can use it to translate to GS1.

[Riot]

Originally Posted by godofwarares

In GS1:

* I love how when people ask for GS1, everyone gives him GS2 ...

You almost had it right:

if (created)
{
     this.sethearts = 10;
     this.setsword = 2;
}

if (playerenters)
{
     setstring clientr.setsword,#v(playerswordpower);
     setstring clientr.sethearts,#v(playerfullhearts);
     playerswordpower = this.setsword;
     playerfullhearts = this.sethearts;

     setplayerprop #c,Default stats set!;
}

if (playerleaves)
{
     playerswordpower = strtofloat(#s(clientr.setsword));
     playerfullhearts = strtofloat(#s(clientr.sethearts));
     setstring clientr.setsword,;
     setstring clientr.sethearts,;

     setplayerprop #c,Original Stats Restored;
}