check if player is staff

[callimuc]

hey i wanted to ask if there is such a command that checks if a player is staff written in the server options (so i don´t use like

PHP Code:

if (player.guild == "Owner") {
blabla
} 


since i think it would make the script too long to add all staff)

i hope there is such a command since i thought i have already seen it somewhere but could find it. it was like:

PHP Code:

function onCreated() {
  is.staff();
}
function onis.staff() {
  //here the script ´looked´ up in the serverv options
  //if the player is a staff member;
} 


i hope i was clear enough what exactly i need

-callimuc

[cbk1994]

There's TServerPlayer.isAdmin and TServerPlayer.isStaff but I'm not sure if either work right—I've had issues with them in the past.

This will always work:

PHP Code:

function isStaff(account) {
  return serveroptions.staff.tokenize(",").index(@ account) > (- 1);
} 


You might want to put something like that in a player class for convenience (using this.account instead of account, obviously).

[DustyPorViva]

You don't have to tokenize the serveroptions staff list, it should be read as an array

[callimuc]

Originally Posted by DustyPorViva

You don't have to tokenize the serveroptions staff list, it should be read as an array

uhm usually idk how to use arrays... is there any easy example i can look up or does the wiki have it? (pretty sure they hae )

[fowlplay4]

Originally Posted by callimuc

uhm usually idk how to use arrays... is there any easy example i can look up or does the wiki have it? (pretty sure they hae )

Posted not too long ago.

Originally Posted by fowlplay4

Here's my quick run-through on Arrays which are useful in managing Collections or Lists of values.

Arrays

PHP Code:

function onCreated() {

  // Creating an Array
  this.array = {1, 2, 3};

  // Reading from an Array (Reading Element in Position 1)
  // Syntax: this.array[element_index]
  // Arrays are 0-based so in our example:
  // this.array[0] is 1
  // this.array[1] is 2
  // this.array[2] is 3
  temp.element = this.array[1];
  echo("Element: " @ temp.element);

  // Changing a Specific Element in an Array
  this.array[2] = 3.14;
  display_array();

  // Adding to an Array
  this.array.add(4);
  display_array();

  // Removing from an Array
  this.array.remove(1);
  display_array();

  // Inserting into an Array (Inserts 2.5 into Position 1)
  this.array.insert(1, 2.5);
  display_array();

  // Deleting from an Array (Deletes Element in Position 1);
  this.array.delete(1);
  display_array();

  // Combining Arrays
  temp.newarray = {5, 6, 7};
  this.array.addarray(temp.newarray);
  display_array();

  // Getting the Size / Number of Elements in Array
  temp.elements = this.array.size();
  echo("Array contains " @ temp.elements @ " elements!");
}

function display_array() {
  echo("Array: " @ this.array);
} 


[callimuc]

whoops ok thanks.

Originally Posted by fowlplay4

Posted not too long ago.

jea i couldnt really understand it but now ill try it xP

[cbk1994]

Originally Posted by DustyPorViva

You don't have to tokenize the serveroptions staff list, it should be read as an array

It doesn't . One of Graal's stupid quirks.

PHP Code:

function onCreated() {
  echo("without: " @ serveroptions.staff[0]);
  echo("with: " @ serveroptions.staff.tokenize(",")[0]);
} 


produces

without: Clockwork,[FOUNDER],HoudiniMan,[DIRECTORS],Tigairius,Chompy,... (trimmed the rest off)
with: Clockwork

[xXziroXx]

Serveroptions are a list of strings, so of course you have to tokenize it to produce an array.

[cbk1994]

Originally Posted by xXziroXx

Serveroptions are a list of strings, so of course you have to tokenize it to produce an array.

PHP Code:

function onCreated() {
  temp.myString = "one,two,three";
  echo(myString[0]);
} 


produces:

one

Welcome to Graal...

[DustyPorViva]

Originally Posted by xXziroXx

Serveroptions are a list of strings, so of course you have to tokenize it to produce an array.

O.o this is what I use for parsing a list of Testbed contacts on testbed:

PHP Code:

function onCreated() {
  this.attr[10] = serveroptions.contacts;
}
//#CLIENTSIDE
function onCreated() {
  this.contacts = (this.attr[10]);
}

function onPlayerTouchsMe() {
  for (temp.i:this.contacts) {
    temp.post @= " " @ i @ "" NL "";
  }
} 


and it works fine.

[callimuc]

so can i use like

PHP Code:

function onPlayerChats() {
if (player.chat == "/test") {
function isStaff(account) {
  return serveroptions.staff.tokenize(",").index(@ account) > (- 1);
  dothestuff;
}
}
} 


[cbk1994]

Originally Posted by callimuc

so can i use like

PHP Code:

function onPlayerChats() {
if (player.chat == "/test") {
function isStaff(account) {
  return serveroptions.staff.tokenize(",").index(@ account) > (- 1);
  dothestuff;
}
}
} 


PHP Code:

function onPlayerChats() {
  if (player.chat == "/test") {
    if (isStaff(player.account)) {
      // do stuff
    }
  }
}

function isStaff(account) {
  return serveroptions.staff.tokenize(",").index(@ account) > (- 1);
} 


Functions have to go outside of any other function.

[fowlplay4]

When checking if they're Staff I like to use a clientr variable and add Staff weapons and tools accordingly.

In your Control-NPC:

PHP Code:

function onActionPlayerOnline() {
  // Check if Player Is Staff
  clientr.isStaff = isStaff(player.account);
  // Add Staff Weapons if Neccesary
  if (clientr.isStaff) {
    player.addweapon("-Staff/SuperSecretAwesomeTool");
  }
}

function isStaff(account) { 
  return serveroptions.staff.tokenize(",").index(@ account) > (- 1); 
} 


Then in your other scripts you can use:

PHP Code:

if (clientr.isStaff) {
  // do this because they're staff
} 


[Skyld]

Originally Posted by fowlplay4

PHP Code:

function isStaff(account) { 
  return serveroptions.staff.tokenize(",").index(@ account) > (- 1); 
} 


PHP Code:

function isStaff(temp.account)
{
  return temp.account in serveroptions.staff;
} 


... just to save you from all that ridiculous index() nonsense.

[salesman]

Originally Posted by Skyld

PHP Code:

function isStaff(temp.account)
{
  return temp.account in serveroptions.staff;
} 


... just to save you from all that ridiculous index() nonsense.

Doesn't work.

PHP Code:

temp.acc = "salesman";
echo(temp.acc in serveroptions.staff); // echoes 0
echo(serveroptions.staff.size()); // echoes 0