Arrow buying

[Equinox]

I'm not very good at scripting so...
im trying to make a npc in a shop that takes gralats from you when you say Buy arrows. the script is like this:

if (player.chat=Buyarrows);
(playerdarts += 30);
(tokenize 10);
say2 here you go.;

It gives me the arrows but it does not deduct it from my gralats.
Help please?

[MattKan]

Originally Posted by Equinox

I'm not very good at scripting so...
im trying to make a npc in a shop that takes gralats from you when you say Buy arrows. the script is like this:

if (player.chat=Buyarrows);
(playerdarts += 30);
(tokenize 10);
say2 here you go.;

It gives me the arrows but it does not deduct it from my gralats.
Help please?

This should work:

PHP Code:

function onPlayerChats()
{
 if (player.chat == "Buyarrows")
  {
   player.darts += 30;
   player.rupees -= 30;
   say2("Here you go!");
  }
} 


However, that raises another issue. Players will be able to buy darts even if they have no gralats. So you have to add an if statement to check for that.

New Script:

PHP Code:

function onPlayerChats()
{
 if (player.chat == "Buyarrows")
  {
   if (player.rupees >= 30)
    {
     player.darts += 30;
     player.rupees -= 30;
     say2("Here you go!");
    }
   else
    {
     say2("You do not have enough gralats.");
    }
  }
} 


That ought to stop players from buying arrows when they have no money.

Oh, and that is GS2, not GS1 which you used in your post. GS2 works better, so I suggest you learn that instead. There are some guides for GS2 scripting here: http://wiki.graal.net/index.php/Creation/Dev/GScript

[Deas_Voice]

if your going to do a "system" for buying items, you could use a gui window instead

there's too muh player commands

[Equinox]

ok thanks now it's working

[Equinox]

ok now its working

[xAndrewx]

hmm

function onPlayerChats() {
  if (player.chat != "buy arrows") return;
  
  player.chat = this.onBuyArrows();
}
function onBuyArrows() {
  if (player.rupees < 30) return "You don't have enough money! You need 30 gralats";
  
  player.darts += 30;
  player.rupees -= 30;

  return "Yaaaay!! Thanks tuff guy";
}

quite funky

[cbk1994]

Originally Posted by xAndrewx

hmm

You shouldn't name functions with an on prefix. That implies that it is an event.

[Tigairius]

Originally Posted by cbk1994

You shouldn't name functions with an on prefix. That implies that it is an event.

I agree here, usually events only start with "onMyFunction." If it's simply a method to purchase an item you should be using "function purchaseItem" instead of "function onPurchaseItem" unless you trigger the event from trigger() or a scheduleevent(). Naming a function with the prefix of "on" basically is saying you don't expect a return value.

[Cloven]

Originally Posted by Tigairius

I agree here, usually events only start with "onMyFunction." If it's simply a method to purchase an item you should be using "function purchaseItem" instead of "function onPurchaseItem" unless you trigger the event from trigger() or a scheduleevent(). Naming a function with the prefix of "on" basically is saying you don't expect a return value.

I generally agree, though I don't think it's a big deal really...

Some people prefix their functions in that fashion for added readability. This is largely because many jerks create unintuitive names for functions, or their code is haphazardly styled. In those cases the 'Find' feature can be rendered almost useless. As such, scanning for the 'on' prefix can be of use in those cases.

For people who practice poor function and/or variable naming... @ you.

[cbk1994]

Originally Posted by Cloven

I generally agree, though I don't think it's a big deal really...

Some people prefix their functions in that fashion for added readability. This is largely because many jerks create unintuitive names for functions, or their code is haphazardly styled. In those cases the 'Find' feature can be rendered almost useless. As such, scanning for the 'on' prefix can be of use in those cases.

How does "on" make a function more readable?

[Fulg0reSama]

Originally Posted by cbk1994

How does "on" make a function more readable?

I think he means if it looks the same as the rest people will recognize it as to what it is.
Also makes narrowing down for functions easier.

[MrOmega]

Originally Posted by cbk1994

How does "on" make a function more readable?

cause then you can capitalize the letter after! :P

onSomeFunction()

-or-

someFunction()

pointless, I know. xP

[MattKan]

I decided to help further by making you a GUI shopping system in which you can purchase bombs and arrows:

PHP Code:

function onActionServerSide(action) {
  switch (action) {
    case "DecRup":
      player.rupees -= params[1];
    break;
  }
}

//#CLIENTSIDE
function onCreated() {
 new GuiWindowCtrl("Bomb_Window") {
   clientextent = "300,200";
   profile = GuiBlueWindowProfile;
   x = screenwidth/2-150;
   y = screenheight/2-100;
   visible = true;

   text = "Get your bombs and arrows!";
   canmove = true;
   canresize = false;
   canmaximize = false;
 
   new GuiShowImgCtrl("Bomb_Img") {
     x = 55;
     y = 80;
     width = 32;
     height = 32;
     this.image = "bomb.png";
    }
   new GuiShowImgCtrl("Bomb_Img2") {
     x = 210;
     y = 80;
     width = 32;
     height = 32;
     this.image = "arrow.png";
    }
 
   new GuiMLTextCtrl("Bomb_Text") {
     profile = GuiBlueMLTextProfile;
     x = 30;
     y = 35;
     width = 430;     
     height = 50;
     text = "<font size=28><font color=white><b>Bombs:</b></font></font>";
    }
   new GuiMLTextCtrl("Bomb_Text2") {
     profile = GuiBlueMLTextProfile;
     x = 10;
     y = 130;
     width = 430;
     height = 50;
     text = "<font size=13.5><font color=white><b>10 Bombs for 10 Gralats.</b></font></font>";
    }
   new GuiMLTextCtrl("Bomb_Text3") {
     profile = GuiBlueMLTextProfile;
     x = 170;
     y = 35;
     width = 430;
     height = 50;
     text = "<font size=28><font color=white><b>Arrows:</b></font></font>";
    }
   new GuiMLTextCtrl("Bomb_Text4") {
     profile = GuiBlueMLTextProfile;
     x = 160;
     y = 130;
     width = 430;
     height = 50;
     text = "<font size=13.5><font color=white><b>20 Arrows for 10 Gralats.</b></font></font>";
    }
   new GuiButtonCtrl("Bomb_Button1") {
     profile = GuiBlueButtonProfile;
     x = 20;
     y = 155;
     width = 100;
     height = 30;
     text = "Purchase";
    }
   new GuiButtonCtrl("Bomb_Button2") {
     profile = GuiBlueButtonProfile;
     x = 170;
     y = 155;
     width = 100;
     height = 30;
     text = "Purchase";
    }
  }
}

function Bomb_Button1.onAction() {
  //Button "Purchase"
 if (player.rupees >= 9) {
   triggerserver("gui",this.name,"DecRup",10);
   player.bombs += 10;
  }else
    player.chat = "Insufficient Funds";
}

function Bomb_Button2.onAction() {
  //Button "Purchase"
 if (player.rupees >= 9) {
   triggerserver("gui",this.name,"DecRup",10);
   player.darts += 20;
  }else
    player.chat = "Insufficient Funds";
} 


I've also included a .txt file.

[Cubical]

Should check to see how many rupees is decreased serverside instead of clientside.

[Tigairius]

Originally Posted by Cubical

Should check to see how many rupees is decreased serverside instead of clientside.

I would check both clientside and serverside. That way if they aren't hacking, it won't send a needless trigger to the server.