Offline Player Manipulation

[fowlplay4]

Allows you to view and edit variables and the values of offline players while providing compatibility methods to edit them if they're already online.

PHP Code:

function findplayer2(acct) {
  // Check if Player Online
  temp.obj = findplayer(acct);
  if (temp.obj.level == NULL) {
    // Create Player Object
    temp.obj = new TServerPlayer(@acct);
  }
  return temp.obj;
}

function getPlayerVar(acct, var) {
  // Get Player Object
  temp.obj = findplayer2(acct);
  temp.val = makevar("temp.obj." @ var);
  // Destroy Player Object
  if (temp.obj.level == NULL) temp.obj.destroy();
  // Return Value
  return temp.val;
}

function editPlayerVar(acct, var, value) {
  // Get Player Object
  temp.obj = findplayer2(acct);
  // Check for Array of Variables and Values
  if (var.type() == 3 && var.size() == value.size()) {
    // Change Values
    for (temp.v: var) {
      makevar("temp.obj." @ var) = value[0+temp.i];
      temp.i++;
    }
  } else {
    // Change Single Value
    makevar("temp.obj." @ var) = value;
  }
  // Save Account File
  if (temp.obj.level == NULL) {
    temp.obj.saveaccount();
    temp.obj.destroy();
  }
} 


Some example usage..

PHP Code:

function onCreated() {
  // Accessing Player Variables
  echo(findplayer2("fowlplay4").account); // Echos fowlplay4
  echo(getPlayerVar("fowlplay4", "account")); // Echos -2144485044 on Zodiac
  // Multiple Variable Value Edit
  editPlayerVar("fowlplay4", {"client.a", "client.b"}, {1, 2});
  // Single Variable Value Edit
  editPlayerVar("fowlplay4", "client.c", 3);
} 


Important Note when using findplayer2:

Originally Posted by Stefan

You need to call destroy() on the player object after you have used it, when you do new TServerPlayer() it is not automatically destroyed like TStaticVars()

Enjoy!

[cbk1994]

I didn't know you could edit variables of offline players, this is quite awesome. Nice work .

[Tigairius]

Originally Posted by cbk1994

I didn't know you could edit variables of offline players, this is quite awesome. Nice work .

I thought I explained that to you ages ago.

Anyways, nice job Jerret, it's a good contribution.

[fowlplay4]

Originally Posted by cbk1994

I didn't know you could edit variables of offline players, this is quite awesome. Nice work .

Found the saveaccount function today in the new serverside_scriptfunctions.txt

You can even join your classes to it, treat it like an online object, and save it when you're done with it too. (No more trivial edits with /open on scammer's accounts :3)

[Admins]

Nice script.
One problem which needs to be solved: you need to call destroy() on the player object after you have used it, when you do new TServerPlayer() it is not automatically destroyed like TStaticVars()

[fowlplay4]

Originally Posted by Stefan

Nice script.
One problem which needs to be solved: you need to call destroy() on the player object after you have used it, when you do new TServerPlayer() it is not automatically destroyed like TStaticVars()

Edited my functions, they destroy properly now.

[WhiteDragon]

Nice. You've been cranking out sweet scripts for some time now! Thanks.

[coreys]

Ooo, nice, I didn't know you could manipulate players offline either, will definitely be using this.

[fowlplay4]

Stefan added a findplayer2 (which now accepts both account and community names) function, which kind of breaks my code snippet.

I've since used this code instead of my findplayer2 function:

PHP Code:

function onCreated() {
  // Load Player
  temp.pl = findplayer(acct);
  temp.offline = temp.pl == NULL;
  temp.pl = temp.offline ? new TServerPlayer(@acct) : temp.pl;
  // Manipulate player object...
  // Save and destroy
  if (temp.offline) {
    temp.pl.saveaccount();
    temp.pl.destroy();
  }
} 


[Astram]

How would I use this to remove an offline players weapon? I can't figure out how.

[fowlplay4]

Originally Posted by Astram

How would I use this to remove an offline players weapon? I can't figure out how.

After you have the player loaded (assuming using temp.pl for the player object):

temp.pl.removeweapon("Weapon Name");

[Astram]

Originally Posted by fowlplay4

After you have the player loaded (assuming using temp.pl for the player object):

temp.pl.removeweapon("Weapon Name");

Sorry for asking, but I don't really understand your main script too much. If you could explain how I could use this in removing a players weapon I'd be glad. Basically I just don't know where to put this chunk of script :P.

[fowlplay4]

Originally Posted by Astram

Sorry for asking, but I don't really understand your main script too much. If you could explain how I could use this in removing a players weapon I'd be glad. Basically I just don't know where to put this chunk of script :P.

After the player object is found/loaded:

PHP Code:

function onCreated() { 
  // Load Player
  temp.acct = "fowlplay4";
  temp.pl = findplayer(acct); 
  temp.offline = temp.pl == NULL; 
  temp.pl = temp.offline ? new TServerPlayer(@acct) : temp.pl; 
  // Manipulate player object... 
  temp.pl.removeweapon("Weapon Name");
  // Save and destroy 
  if (temp.offline) { 
    temp.pl.saveaccount(); 
    temp.pl.destroy(); 
  } 
}