Roman numbers

[Chompy]

Well, gives the ability to convert numbers into roman numbers and vice versa:

PHP Code:

public function romanToNumber(roman) {
  temp.table_l = {"M","CM","D","CD","C","XC","L","XL","X","IX","V","IV","I"};
  temp.table_n = {1000,900,500,400,100,90,50,40,10,9,5,4,1};
  temp.n = 0;
  for(temp.i = 0; i < roman.length(); i ++) {
    if (roman.substring(i, 2) in table_l) {
      n += table_n[table_l.index(roman.substring(i, 2))];
      i ++;
    }else n += table_n[table_l.index(roman.charat(i))];
  }
  return n;
}
public function numberToRoman(number) {
  temp.table_n = {1000,900,500,400,100,90,50,40,10,9,5,4,1};
  temp.table_l = {"M","CM","D","CD","C","XC","L","XL","X","IX","V","IV","I"};
  temp.out = "", temp.number2 = number;
  for(temp.n : table_n) {
    while(number2 >= n) {
      number2 -= n;
      out @= table_l[table_n.index(n)];
    }
  }
  return out;
} 


(Credits to Ian )

Example:

PHP Code:

function onCreated() {
  echo(numberToRoman(947));
  echo(romanToNumber("CMXLVII"));
  /*
  CMXLVII
  947
  */
  echo(numberToRoman(2008));
  echo(romanToNumber("MMVIII"));
  /* 
  MMVIII
  2008
  */
  echo(numberToRoman(romanToNumber("MMVIII")));
  // MMVIII
} 


anyways, enjoy?