Help with a for loop problem?

[DeCeaseD]

Okay so, I'm using a for loop to check through a multi-dimensional array, and everything is returning fine, the script is basically doing what I want it to do, no problem. But now within the for loop i'm trying to set an individual this.whatever flag everytime I mouse over an object in the array. (If this makes sense?) But for some reason, I can only set the flag for the last group of variables in the array.. ?

I dunno if what I just said makes any sense, but either way, check out the code and you'll probably see what I mean.. By the way, I am merely providing the pieces of the code that are needed in order for me to get help, the //Mouse Over part is being ran within a timeout loop just to clarify things a bit more..

Also, another clarification: I'm trying to set this.newDebug to true everytime the mouse enters the specified zone, but I can only set it for the "Rifle" array part. It won't set for any others. =/

Thanks in advance to anyone that helps.

PHP Code:

function onCreated()
{
  this.equipSlots = { {"Hat", 36, 58, "necro_gui_equips-hat.png"},
                      {"Mask", 96, 58, "necro_gui_equips-mask.png"},
                      {"Armor", 156, 58, "necro_gui_equips-armor.png"},
                      {"Back Piece", 36, 118, "necro_gui_equips-back.png"},
                      {"Shirt", 156, 118, "necro_gui_equips-shirt.png"},
                      {"Glove", 36, 178, "necro_gui_equips-glove.png"},
                      {"Pants", 156, 178, "necro_gui_equips-pants.png"},
                      {"Shoes", 96, 209, "necro_gui_equips-shoes.png"},
                      {"Explosive", 36, 233, "necro_gui_equips-explosive.png"},
                      {"Left Weapon", 36, 288, "necro_gui_equips-leftwep.png"},
                      {"Right Weapon", 156, 288, "necro_gui_equips-rightwep.png"},
                      {"Rifle", 96, 264, "necro_gui_equips-rifle.png"}
                   };
  this.equipSlotCount = 12;
}

    //Mouse over for Slot
    temp.mouse_xy = {mousescreenx, mousescreeny};
    for ( i=0; i < this.equipSlotCount; i++; ) {
      
      temp.chSlots = this.equipSlots[i];
      if ( mouse_xy[0] in |menu_xy[0] + chSlots[1], menu_xy[0] + chSlots[1] + 32| &&
           mouse_xy[1] in |menu_xy[1] + chSlots[2], menu_xy[1] + chSlots[2] + 32| ) {
        this.newDebug = true;
        with ( findImg ( 203 + i ) ) {
        
          image = chSlots[3];
          x = menu_xy[0] + chSlots[1];
          y = menu_xy[1] + chSlots[2];
          layer = 5;
          mode = 0;
          red = green = blue = 1;
          alpha = .8;
        }
        with ( findImg ( 223 + i ) ) {
        
          text = chSlots[0];
          font = "Tempus Sans ITC";
          style = "bc";
          x = menu_xy[0] + chSlots[1] + 16;
          y = menu_xy[1] + chSlots[2] - 5;
          layer = 5;
          mode = 0;
          red = green = blue = 1;
          alpha = .8;
          textshadow = true;
          shadowcolor = {0, 0, 0};
          zoom = .6;
        }
      } else {       
        hideImg( 203 + i ); 
        hideImg( 223 + i ); 
        this.newDebug = false;
      }
    } 


[salesman]

The reason it only works for the rifle is because it is the last member of the array. It is being set to true properly for the rest of them, but you're also immediately setting it back to false in the next loop iteration.

Try breaking out of the loop after you set it to true (and have performed all of your logic).

edit: if you still need to hide remaining images, play with hideImgs(start, end). There's really no need to continue looping to hide the rest of the images because you know exactly how many you have

PHP Code:

// Hide remaining images
hideImgs(203 + i + 1, 203 + this.equipSlotCount);
hideImgs(223 + i + 1, 223 + this.equipSlotCount);

break; // break out of your loop 


might have failed at math, but you get the idea

[DeCeaseD]

Originally Posted by salesman

The reason it only works for the rifle is because it is the last member of the array. It is being set to true properly for the rest of them, but you're also immediately setting it back to false in the next loop iteration.

Try breaking out of the loop after you set it to true (and have performed all of your logic).

How exactly would I break out of the loop though, I don't really get it.

[salesman]

Originally Posted by DeCeaseD

How exactly would I break out of the loop though, I don't really get it.

Something like this, although I haven't tested obviously:

PHP Code:

    //Mouse over for Slot
    this.newDebug = false; // assume false
    temp.mouse_xy = {mousescreenx, mousescreeny};
    for ( i=0; i < this.equipSlotCount; i++; ) {
      temp.chSlots = this.equipSlots[i];
      if ( mouse_xy[0] in |menu_xy[0] + chSlots[1], menu_xy[0] + chSlots[1] + 32| &&
           mouse_xy[1] in |menu_xy[1] + chSlots[2], menu_xy[1] + chSlots[2] + 32| ) {
        this.newDebug = true;

        ///// snip your image stuff //////

        // Hide remaining images
        hideImgs(203 + i + 1, 203 + this.equipSlotCount);
        hideImgs(223 + i + 1, 223 + this.equipSlotCount);

        // break out of the loop b/c we only have one mouse location and we already know which object it's hovering over
        break;
      } else { // Keep this to hide the images before we find one that's true   
        hideImg(203 + i); 
        hideImg(223 + i);
      }
    } 


[DeCeaseD]

Wow.. stupid of me. When you said to break out of the loop for someone reason I was thinking of something totally different. Forgot all about break; *****. But all I needed to do was assume it false like you said, than break out of the loop. Thanks alot Sales! ily!

[salesman]

Originally Posted by DeCeaseD

Wow.. stupid of me. When you said to break out of the loop for someone reason I was thinking of something totally different. Forgot all about break; *****. But all I needed to do was assume it false like you said, than break out of the loop. Thanks alot Sales! ily!

=p
Keep in mind that if you just simply break out of the loop you're no longer hiding the remaining images, so you'll need to do something about that like I showed above.

[DeCeaseD]

Originally Posted by salesman

=p
Keep in mind that if you just simply break out of the loop you're no longer hiding the remaining images, so you'll need to do something about that like I showed above.

Yeah I got it.

But aside from that, I've ran into another odd issue..

I'm making this menu fade in/out when opened/closed, using this.menu_alpha, increasing and decreasing the value. It all works fine. Except now i've tried to add an actor into the middle of the menu, but the problem being that I can't seem to get it to fade with the menu:

PHP Code:

    with ( findImg( 300 ) ) {
    
      ani = "necro_body_idle";
      x = menu_xy[0] + getimgWidth("necro_gui_equips.png")/2.53;
      y = menu_xy[1] + getimgHeight("necro_gui_equips.png")/2.6;
      dir = 2;
      layer = 5;
      mode = 1;
      red = green = blue = 1;
      partx = 0;
      party = 0;
      partw = 41;
      parth = 68;
      actor.attr[1] = player.attr[1];
      actor.attr[2] = player.attr[2];
      actor.attr[3] = player.attr[3];
      actor.attr[4] = player.attr[4];
      actor.attr[5] = player.attr[5];
      actor.attr[6] = player.attr[6];
      actor.attr[7] = player.attr[7];
      actor.attr[8] = player.attr[8];
      actor.attr[9] = player.attr[9];
      actor.attr[10] = player.attr[10];
      actor.attr[11] = player.attr[11];
      actor.attr[12] = player.attr[12];
      actor.attr[13] = player.attr[13];
      actor.attr[14] = player.attr[14];
    } 


That's the code i'm using to display the actor, I can see it fine but the alpha won't change like I want it to. I'm using findImg( 300 ).alpha = this.menu_alpha; Any idea why it won't fade with the menu? :x

[fowlplay4]

Originally Posted by DeCeaseD

That's the code i'm using to display the actor, I can see it fine but the alpha won't change like I want it to. I'm using findImg( 300 ).alpha = this.menu_alpha; Any idea why it won't fade with the menu? :x

this.menu_alpha is most likely 0/NULL in the context/scope of the findimg.

thiso.menu_alpha is what you're aiming for.

[DeCeaseD]

Originally Posted by fowlplay4

this.menu_alpha is most likely 0/NULL in the context/scope of the findimg.

thiso.menu_alpha is what you're aiming for.

I've actually already tried using thiso. But it's not the problem. I've found that you only need to use thiso. in context with findimg when you're setting something within the original 'with (findImg( index ) )', otherwise you can normally use this. by setting whatever findImg( index ).part = whatever;

Any ideas as to what else the problem could be?

[DeCeaseD]

Anyone? No one?

[fowlplay4]

You could try using a gani script. I.e:

actor.attr[30] = "alpha.gani,0.5";

Gani: alpha.gani

PHP Code:

SCRIPT
function onPlayerEnters() {
  player.alpha = params[0];
}
SCRIPTEND 


It might be bugged though, I remember a similar problem.