Bank System

[Twinny]

Bank system I made using dbnpc.

DBNPC Script (Name is BankDB):

PHP Code:

function onCreated()
{
  this.interest = 0.01;
  this.hour = 0;
  Interest();
  setTimer(3600);
}
public function CreateAccount(pl,ammount)
{
  if (this.accounts.index(pl) = -1)
  {
    this.accounts.add(pl);
    this.("acc"@pl) = ammount;
    findplayer(pl).rupees -= ammount;
    return true
  }
  else return false;
}

public function CheckBalance(pl)
{
  if (this.accounts.index(pl) => 0)
  {
    return this.("acc"@pl);
  }
  else return false;
}  

public function AddMoney(pl,ammount)
{
  if (this.accounts.index(pl) => 0)
  {
    findplayer(pl).rupees -= ammount;
    this.("acc"@pl) += ammount;
    return this.("acc"@pl);
  }
  else return false;
}  

public function RemoveMoney(pl,ammount)
{
  if (this.accounts.index(pl) => 0)
  {
    if (this.("acc"@pl) => ammount)
    {
      this.("acc"@pl) -= ammount;
      findplayer(pl).rupees += ammount;
      return true;
    }
    else return "nm";
  }
  else return "na";
}

function onTimeout() 
{
/* Cheers to Kuji for this.hour idea */
  this.hour ++;
  if (this.hour => 24)
  {
    echo("Interest Added");
    Interest();
    this.hour = 0;
  }
setTimer(3600);
} 

public function Interest()
{
  for (int : this.accounts)
  {
    this.("acc"@int) = int(this.("acc"@int) * 1.01);
  }
} 


Manual interest for RC - add this to your Control-NPC

PHP Code:

 function onRCChat()
{
  if (params[0] == "interest")
  {
    if (player.account == "Whoever")
    {
      echo("Manual Interest Added!");
      BankDB.Interest();
    }
  }
} 


And finally some examples on how to use this system in a bank

PHP Code:

/* Do not clientside this script */
function onPlayerChats()
{
  /*Create Account*/
  if (player.chat.starts("/createaccount"))
  {
    temp.result = BankDB.CreateAccount(player.account,player.chat.substring(15,-1));
    if (temp.result == true)
      say2("Account Opened");

    else say2("You already have an account");
   }

  else if (player.chat == "/balance")
  {
    temp.result = BankDB.CheckBalance(player.account);
    if(temp.result != false)
      say2("Current Balance" SPC temp.result);
    else say2("You do not have an account");
   }

   else if (player.chat.starts("/withdraw"))
   {
     temp.result = BankDB.RemoveMoney(player.account,player.chat.substring(10,-1));
     if (temp.result == "na")
       say2("Open an account?");
     else if (temp.result == "nm")
       say2("Not enough money");
     else if (temp.result ==  true)
       say2("Withdrawn");
    }
   else if (player.chat.starts("/deposit"))
   {
        if (player.rupees > player.chat.substring(9,-1))
        {
          temp.result = BankDB.AddMoney(player.account,player.chat.substring(9,-1));
          if (temp.result != false)
            say2("Money Deposited. Balance: " @ temp.result);
          else
            say2("Open an account first");
        }
    }
} 


This system can work on a global scale. One BankDB can serve any ammount of banks. I used a BankDB for a couple of reasons. First off - incredibly easy to add interest now. Secondly - I can use functions to determine who has the most money, total ammount of money etc. (Not included).

[Skyld]

Slightly different approach to how I would do it, but good none the less.

[KuJi]

Originally Posted by Twinny

public function CreateAccount(pl,ammount)

Take a look at the bolded twinny

[Twinny]

So I can't spell for peanuts. Does this really matter? No? Good .

[xAndrewx]

Originally Posted by Skyld

Slightly different approach to how I would do it, but good none the less.

I agree :S
Good though

[Twinny]

Ok: How would you two do it?

[xAndrewx]

Personally, I'd merge the Create account and Deposit into one. If the string inside the database doesn't exist, I'd then instantly create the bank account. I wouldn't use so many public functions, remember that they're public. I'd also convert your playerchats.

[KuJi]

Clientside -> Trigger to Server -> Use ChatBar -> Ftw =O?

[Skyld]

Originally Posted by Twinny

Ok: How would you two do it?

Well, the way that my system works is that I have a collection of public functions in a class which is joined to the player.

PHP Code:

public function bankCreate();
public function bankDeposit();
public function bankWithdraw(); 


I also have other functions for checking if they have an account, checking the balance, etc.

I also have a DB NPC for storing the bank data, i.e.

PHP Code:

DB_Bank.("bank_" @ this.account) = ...; 


However, but it doesn't do any functioning itself.

Then, instead of having to pass the account name, I can just use the this. object to access the player so that you can just do this to deposit 30g:

PHP Code:

player.bankDeposit(30); 


It makes it:

• Easier to type, and remember.
• Easier for other people to pick up and use.
• So that you don't have to pass the account name.

[KuJi]

Hmm.. my atms a bit diff =o.

acc_123456=KuJi,PASSWORD,BALANCE

I should probally MD5 the password, maybe I will redo the ATM sometime soon.. is kinda old.

Anyway, when you use your ATM Card it has the ATM # in it automatically... so yeah.

[Twinny]

Originally Posted by xAndrewx

I'd also convert your playerchats.

The playerchat stuff was just an example to show how to do it. Hopefully people will use something better eg a GUI.

That's a pretty good idea Skyld. May edit the code with a more user friendly version later . I'm still pretty sucky at scripting but anything that seems half decent to me i'll share in the hope of receiving advice

[xAndrewx]

Skyld's idea is good :]

[k0rupt_ed]

you people inspire me.

[Twinny]

To do what?

[Twinny]

Update!
Bank System v 1.1
After receving advice from Skyld I have made a improved bank system using classes.

DBNPC named BankDB

PHP Code:

function onCreated()
{
  this.interest = 0.01;
  this.hour = 0;
  Interest();
  setTimer(3600);
}

function onTimeout()
{
  this.hour ++;
  if (this.hour => 24)
  {
    echo("Interest Added");
    Interest();
    this.hour = 0;
  }
setTimer(3600);
} 

public function Interest()
{
  for (int : this.accounts)
  {
    this.("acc"@int) = int(this.("acc"@int) * 1.01);
  }
} 


Class with bank functions

PHP Code:

public function bankCreate(amount)
{
  if (BankDB.accounts.index(player.account) = -1)
  {
    if (player.rupees => amount)
    {
      BankDB.accounts.add(player.account);
      BankDB.("acc"@player.account) = amount;
      player.rupees -= amount;
      return True;
    }
    else return "nem";  
  }
  else return false;
}

public function bankDeposit(amount)
{
  if (BankDB.accounts.index(player.account) => 0)
  {
    if (player.rupees => amount)
    {
      BankDB.("acc"@player.account) += amount;
      player.rupees -= amount;
      return true;
    }
    else return "nem"; //Not enough money
  }
  else return "nba"; //No bank account  
}

public function bankWithdraw(amount)
{
  if (BankDB.accounts.index(player.account) => 0)
  {
    if (BankDB.("acc"@player.account) => amount)
    {
      BankDB.("acc"@player.account) -= amount;
      player.rupees += amount;
      return true;
    }
    else return "nem";
  }
  else return "nba";   
}

public function bankBalance()
{
  if (BankDB.accounts.index(player.account) => 0)
  {
    return BankDB.("acc"@player.account);
  }
  else return "nba";
}

public function bankTransfer(amount,pl)
{
/* Lot's of Tests */
  if (BankDB.accounts.index(player.account) => 0)
  {
    if(BankDB.accounts.index(pl) => 0)
    {
      if (BankDB.("acc"@player.account) => amount)
      {
        BankDB.("acc"@pl) += amount;
        BankDB.("acc"@player.account) -= amount;
        return true;
      }
      else return "nem";
    }
    else return "pdne"; //Player does not exist
  }
  else return "nba";
} 


Finally add in your Control-NPC

PHP Code:

function onActionPlayeronline()
{
  player.join("classname");
}

function onRCChat()
{
  if (params[0] == "interest")
  {
    if (player.account == "Whoever")
    {
      echo("Manual Interest Added!");
      BankDB.Interest();
    }
  }
} 


Commands Available

PHP Code:

player.bankCreate(amount);
player.bankDeposit(amount);
player.bankWithdraw(amount);
player.bankBalance();
player.bankTransfer(amount,account); 


Simple enough to use. Call the commands serverside eg. player.bankDeposit(400);

May add a GUI script to use the Bank system next.